pro ell_of_T,lambda,T,ell
; IDL procedure to calculate the absorption length ell or its
; reciprocal alpha using the parameterization of Rajkanan, Singh, and
; Shewchun, Solid-State Electronics 22, 793-795, 1979.

; lambda (in nm) is assumed to be an array, and T a scaler. 
; The calculated absoption length ell, in microns, will have the 
; same dimensions as lambda.

; First the constants
beta = 7.021e-4 ; eV/K
k    = 8.617E-5   ; eV/K
gamma = 1108.     ; K
E_g0 = fltarr(2)
E_g0(0) = 1.1557   ; eV
E_g0(1) = 2.5      ; eV
E_gd0  = 3.2      ; eV
E_p = fltarr(2)
E_p(0) = 1.827E-2 ; eV
E_p(1) = 5.773E-2 ; eV
C =   fltarr(2)
C(0) = 5.5
C(1) = 4.0
A = fltarr(2)
A(0) = 323.1      ; cm^-1 eV^-2
A(1) = 7237.      ; cm^-1 eV^-2
A_d  = 1.052E6    ; cm^-1 eV^-2

hnu = 1239.842/lambda
E_gd = E_gd0 - beta*T^2/(T + gamma)
E_g = E_g0 - beta*T^2/(T + gamma)
alpha = A_d*sqrt(hnu - E_gd >0.) ; alpha_v
for i = 0,1 do begin
  for j = 0,1 do begin
  denom1 = exp(E_p(i)/(k*T)) - 1.
  denom2 = 1. - exp(-E_p(i)/(k*T))
  piece = C(i)*A(j)*( (hnu - E_g(j) + E_p(i) > 0.)^2 / denom1 + $
	(hnu - E_g(j) - E_p(i) > 0.)^2 / denom2  )
     alpha = alpha + piece
  endfor
endfor
ell = 10000./alpha
end